Cada numeración de las cuentas corrientes es único y por ello deben contener algún tipo de control para que no se comentan errores en el momento de copiar la numeración o sea más complejo el inventar una numeración y este sea correcto. Para ello se utilizan los dígitos de control y se calculan mediante una operación matemática utilizando el resto de datos de la cuenta.
Antes de empezar recordemos la estructura de una cuenta corriente:
Los primeros cuatro dígitos son el Código de la Entidad, que coincide con el Número de Registro de Entidades del Banco de España.
Los siguientes cuatro dígitos identifican la Oficina de nuestra entidad bancaria.
Los siguientes dos dígitos son los llamados Dígitos de Control, que sirven para validar la cuenta corriente y estos son los que aprenderemos a calcular en esta práctica.
Los últimos diez dígitos identifican a la Cuenta del Cliente.
En total son 20 dígitos numéricos: EEEE OOOO DC CCCCCCCCCC
En primer lugar explicaremos qué cálculos hay que realizar y más adelante lo explicaremos utilizando las funciones de excel. Sería interesante que una vez explicado como calcularlo y antes de la explicación más específica para excel intentaras solucionar el problema por tu cuenta y así ver si puedes solucionarlo.
Cálculo del primer dígito de control
Para calcular el primer dígito de control deberemos unir el código de la entidad y el código de la oficina: EEEEOOOO y conseguir tener 10 dígitos, para ello añadiremos dos ceros por la izquierda quedando así 00EEEEOOOO
Cada uno de los dígitos que forman parte del código que acabamos de obtener se multiplica por un factor asociado a su posición. Así, los factores son: 1, 2, 4, 8, 5, 10, 9, 7, 3, 6
El resultado de cada una de las 10 multiplicaciones deberá sumarse, quedando la función de la siguiente forma: 0*1+0*2+E*4+E*8+E*5+E*10+O*9+O*7+O*3+O*6
Ahora deberemos dividir el número obtenido entre 11 y quedarnos con el resto.
A continuación el resto que hemos obtenido se resta de 11 para obtener el primer dígito de control. Sólo nos queda una comprobación más, ya que estamos interesados en obtener una sola cifra, si la cantidad resultante fuese 10, se cambiaría el dígito de control por 1 y si fuese 11 se cambiaría por 0.
¡Ya tenemos el primer dígito de control!
Cálculo del segundo dígito de control
Para realizar el cálculo del segundo dígito de control repetiremos exactamente los mismos cálculos anteriores, pero con el Número de cuenta. Este valor ya tiene 10 dígitos con lo que no deberemos añadir nada y podremos realizar el cálculo directamente.
Ahora que ya sabemos como se calculan en la teoría vamos a pasar estos cálculos a una hoja de excel, pero antes de nada vamos a preparar nuestra hoja de excel de la siguiente forma:
En la fila 1 introduciremos los títulos de las diferentes partes de la cuenta corriente y en las fila 2 el contenido de cada una de las partes de la cuenta corriente con la que queremos trabajar. En la celda C3 deberá aparecer el resultado de nuestros cálculos.
Como es una función con muchas partes y cálculos utilizaremos celdas separadas para todos los cálculos y al final de la función intentaremos agruparlo en una sola celda.
Recordemos que el primer paso es agrupar la entidad bancaria (A2) y la oficina (B2) y añadirle dos 0 a la izquierda. Para ello deberemos trabajar con una cadena alfanumérica, ya que si trabajamos con un número los 0 de la izquierda no aparecerán. Para ello utilizaremos la función TEXTO()
En la celda, por ejemplo, B4 introduciremos la siguiente función
=TEXTO(A2&B2;"0000000000")
de tal forma que el resultado que obtendremos será, según el ejemplo de la imagen 0021001234
Ahora ya podremos realizar toda la serie de multiplicaciones y sumas que explicamos con anterioridad y para ello, recordemos, que debemos ir extrayendo cada valor que ocupa cada una de las diferentes posiciones y multiplicarlo por el valor que hemos detallado en la primera parte de la explicación de esta práctica. Para extraer cada número utilizaremos la función EXTRAE()
Para tener el resultado de esta operación escribiremos la siguiente función en la celda B6 =EXTRAE(B4;1;1)*1+ EXTRAE(B4;2;1)*2+EXTRAE(B4;3;1)*4+ EXTRAE(B4;4;1)*8+EXTRAE(B4;5;1)*5+ EXTRAE(B4;6;1)*10+EXTRAE(B4;7;1)*9+ EXTRAE(B4;8;1)*7+EXTRAE(B4;9;1)*3+ EXTRAE(B4;10;1)*6
El resultado que obtendremos en este ejemplo debe ser 72
Ahora a continuación en la celda B7 calcularemos el resultado de restar 11 al residuo, RESIDUO(), que se obtiene entre el resultado obtenido anteriormente y 11 quedando la función de la siguiente forma =11-RESIDUO(B6;11)
El resultado obtenido debe ser en este ejemplo 5
Ahora solo nos falta verificar si el residuo es 10 o 11 para cambiar el resultado final para ello utilizaremos la función SI() y como tenemos más de una opción utilizaremos un SI dentro de otro SI de tal forma que en la celda B9 introduciremos la función =SI(B7=10;1;SI(B7=11;0;B7))
En este caso como el resultado que hemos obtenido anteriormente es 5, nos quedaremos con ese mismo resultado y no se modificará.
¡Ya tenemos el primer dígito de control, vamos a por el segundo!
Ahora trabajaremos con el número de cuenta. Recuerda que como este valor tiene 10 dígitos no hace falta añadir ningún valor por delante, aunque es conveniente recordad que si trabajamos con valores numéricos y el número de cuenta empieza por 0 estos no se tendrán en cuenta. Así que para evitar problemas en el momento de insertar el valor en la celda D2 podemos empezar con el sigo ‘ con lo que el valor numérico se convertirá en un valor alfanumérico manteniendo los posibles 0 que pueda tener a la izquierda.
Ahora realizaremos el cálculo con cada uno de los números que están en cada posición del número de cuenta.
En la celda D6 introduce la siguiente función =EXTRAE(D2;1;1)*1+EXTRAE(D2;2;1)*2 +EXTRAE(D2;3;1)*4+EXTRAE(D2;4;1)*8 +EXTRAE(D2;5;1)*5+EXTRAE(D2;6;1)*10 +EXTRAE(D2;7;1)*9+EXTRAE(D2;8;1)*7 +EXTRAE(D2;9;1)*3+EXTRAE(D2;10;1)*6
El resultado que deberemos obtener según el ejemplo con el que estamos trabajando sería 280
En la celda D7 realizaremos la resta de 11 y el resultado del residuo del valor obtenido entre 11. La función quedaría de la siguiente forma =11-RESIDUO(D6;11) y el resultado que debemos obtener es 6
Y como último paso volveríamos a verificar si el valor obtenido es 10 u 11 para realizar el cambio correspondiente. Así que en la celda D9 introduciremos la fórmula
=SI(D7=10;1;SI(D7=11;0;D7))
Como en este caso el resultado es 6, nos quedaremos con ese mismo valor.
¡Ahora ya tenemos el segundo dígito de control!
De esta forma en la celda C2 tan solo nos quedaría unir el primer y el segundo dígito de control con la función =B9&D9
En este caso el resultado debe ser 56
Para verificar que todo es correcto puedes introducir el número de tu cuenta bancaria para ver si todo es correcto.
Como hemos podido ver en esta ocasión y para conseguir un resultado correcto nos hemos visto obligados a utilizar muchas funciones y celdas intermedias para encontrar el resultado obtenido. Es casi imposible en un caso así poder realizar el cálculo en una sola celda de una sola vez. Ahora solo nos quedaría ir sustituyendo cada celda que hace referencia a una función o cálculo para intentar conseguir tener en una sola celda todo el cálculo del dígito de control.
La fórmula que obtendríamos después de realizar todos los pasos que hemos visto y que podríamos poner directamente en la celda C2 sería la siguiente:
=SI(11-RESIDUO(EXTRAE(TEXTO(A2&B2;"0000000000");1;1)*1 +EXTRAE(TEXTO(A2&B2;"0000000000");2;1)*2 +EXTRAE(TEXTO(A2&B2;"0000000000");3;1)*4 +EXTRAE(TEXTO(A2&B2;"0000000000");4;1)*8 +EXTRAE(TEXTO(A2&B2;"0000000000");5;1)*5 +EXTRAE(TEXTO(A2&B2;"0000000000");6;1)*10 +EXTRAE(TEXTO(A2&B2;"0000000000");7;1)*9 +EXTRAE(TEXTO(A2&B2;"0000000000");8;1)*7 +EXTRAE(TEXTO(A2&B2;"0000000000");9;1)*3 +EXTRAE(TEXTO(A2&B2;"0000000000");10;1)*6;11)=10;1;SI(11-RESIDUO(EXTRAE(TEXTO(A2&B2;"0000000000");1;1)*1 +EXTRAE(TEXTO(A2&B2;"0000000000");2;1)*2 +EXTRAE(TEXTO(A2&B2;"0000000000");3;1)*4 +EXTRAE(TEXTO(A2&B2;"0000000000");4;1)*8 +EXTRAE(TEXTO(A2&B2;"0000000000");5;1)*5 +EXTRAE(TEXTO(A2&B2;"0000000000");6;1)*10 +EXTRAE(TEXTO(A2&B2;"0000000000");7;1)*9 +EXTRAE(TEXTO(A2&B2;"0000000000");8;1)*7 +EXTRAE(TEXTO(A2&B2;"0000000000");9;1)*3 +EXTRAE(TEXTO(A2&B2;"0000000000");10;1)*6;11)=11;0;11-RESIDUO(EXTRAE(TEXTO(A2&B2;"0000000000");1;1)*1 +EXTRAE(TEXTO(A2&B2;"0000000000");2;1)*2 +EXTRAE(TEXTO(A2&B2;"0000000000");3;1)*4 +EXTRAE(TEXTO(A2&B2;"0000000000");4;1)*8 +EXTRAE(TEXTO(A2&B2;"0000000000");5;1)*5 +EXTRAE(TEXTO(A2&B2;"0000000000");6;1)*10 +EXTRAE(TEXTO(A2&B2;"0000000000");7;1)*9 +EXTRAE(TEXTO(A2&B2;"0000000000");8;1)*7 +EXTRAE(TEXTO(A2&B2;"0000000000");9;1)*3 +EXTRAE(TEXTO(A2&B2;"0000000000");10;1)*6;11)))&SI(11-RESIDUO(EXTRAE(D2;1;1)*1+EXTRAE(D2;2;1)*2 +EXTRAE(D2;3;1)*4+EXTRAE(D2;4;1)*8 +EXTRAE(D2;5;1)*5+EXTRAE(D2;6;1)*10 +EXTRAE(D2;7;1)*9+EXTRAE(D2;8;1)*7 +EXTRAE(D2;9;1)*3+EXTRAE(D2;10;1)*6;11)=10;1;SI(11-RESIDUO(EXTRAE(D2;1;1)*1+EXTRAE(D2;2;1)*2 +EXTRAE(D2;3;1)*4+EXTRAE(D2;4;1)*8 +EXTRAE(D2;5;1)*5+EXTRAE(D2;6;1)*10 +EXTRAE(D2;7;1)*9+EXTRAE(D2;8;1)*7 +EXTRAE(D2;9;1)*3+EXTRAE(D2;10;1)*6;11)=11;0;11-RESIDUO(EXTRAE(D2;1;1)*1+EXTRAE(D2;2;1)*2 +EXTRAE(D2;3;1)*4+EXTRAE(D2;4;1)*8 +EXTRAE(D2;5;1)*5+EXTRAE(D2;6;1)*10 +EXTRAE(D2;7;1)*9+EXTRAE(D2;8;1)*7 +EXTRAE(D2;9;1)*3+EXTRAE(D2;10;1)*6;11)))
Deja una respuesta